Wikidata

Wikidata data model parts

select

     ?wikidataPart_
#  ( substr(str(?part_), 32) as ?qNr )
     ?wikidataPart
{  #
   # Q16354757: Wikidata Data Model
   # P527:      has parts
   #

     wd:Q16354757      wdt:P527      ?wikidataPart_ .
    ?wikidataPart_    rdfs:label     ?wikidataPart  . filter(lang(?wikidataPart) = 'en')

}
order by
   lcase(?wikidataPart)

Parts of the wikidata data model:

select

     ?part_
#  ( substr(str(?part_), 32) as ?qNr )
     ?part
{  #
   # Q16354757: Wikidata Data Model
   # P361:      part of
   #

    ?part_     wdt:P361   wd:Q16354757 .
#   wd:Q16354757     wdt:P361   ?part  .
    ?part_    rdfs:label ?part         . filter(lang(?part) = 'en')

}
order by
   lcase(?wikidataPart)

Entities

Item

Property

Q...

L…

E… (Schema)

Statements

select
  distinct ?rank
{
#  []    <http://wikiba.se/ontology#rank>   ?rank .
   []     wikibase:rank                     ?rank .
}

Namespaces

None and some

SERVICE wikibase:label

select
   ?country
   ?countryLabel
#  ?countryPrefLabel
   ?countryDescription
   ?countryAltLabel
#  ?altLabelDirect
{
    wd:Q188 wdt:P17 ?country .
 # ?country <http://www.w3.org/2004/02/skos/core#altLabel> ?altLabelDirect . filter(lang(?altLabelDirect) = 'en')
    service wikibase:label { bd:serviceParam wikibase:language "en" . }
}

select
   ?x
   ?xLabel
{
   values (?x) {
      (wd:L296666)
      (wd:Q39    )
   }
 
   optional { ?x wikibase:lemma ?xLabel }
   service wikibase:label { bd:serviceParam  wikibase:language  'en,de,fr,rm' }
}

select
   ?lem
   (lang(?L) as ?lng)
{
  ?lem wikibase:lemma ?L .
  {
    select
      ?lem
    { 
      { ?lem wikibase:lemma "ding"@da } union
      { ?lem wikibase:lemma "ding"@en } union
      { ?lem wikibase:lemma "ding"@pt }
    }
  }
}

select
   ?lem
   (lang(?str)     as ?lng)
{
   ?lem wikibase:lemma ?str . filter(str(?str) = "ding")
}

Wikidata Query Service (WDQS)

connecting wd:P… to their counterpart …:P… nodes

select * {
   wd:P10 wikibase:directClaim ?y  .
}

ask {
   wd:P31   wikibase:claim                   p:P31 .
   wd:P31   wikibase:directClaim           wdt:P31 .
   wd:P31   wikibase:novalue              wdno:P31 .
   wd:P31   wikibase:qualifier              pq:P31 .
   wd:P31   wikibase:qualifierValue        pqv:P31 .
   wd:P31   wikibase:reference              pr:P31 .
   wd:P31   wikibase:referenceValue        prv:P31 .
   wd:P31   wikibase:statementProperty      ps:P31 .
   wd:P31   wikibase:statementValue        psv:P31 .
}

wikibase:badge

select
  ?aboutTxt
  ?about
  ?featuredArticle
{
   ?featuredArticle wikibase:badge        wd:Q17437796 ;
                    schema:inLanguage    "de"          ;
                    schema:about         ?about        .
  
   ?about           rdfs:label           ?aboutTxt     .

   filter(lang(?aboutTxt) = 'de')
}
order by lcase(?aboutTxt)

select
   ?cnt
   ?badgeLabel
   ?badge
{
   service wikibase:label { bd:serviceParam wikibase:language "[auto_language],en". }
   {
      select
         (count(*) as ?cnt)
         ?badge
      {
        []  wikibase:badge  ?badge 
      }
      group by
         ?badge
   }
}
order by
   ?badgeLabel

wikibase:Dump

select
   ?type
{
   wikibase:Dump  rdf:type   ?type
}

select
   ?a ?b
{
  wikibase:Dump ?a ?b .
}

select
   ?rel ?x
{
   values (?rel) {
     (<http://creativecommons.org/ns#license>)
     (schema:softwareVersion                 )
     (owl:imports                            )
   }

   wikibase:Dump ?rel ?x .
}

wikibase:identifiers

select
   (max(?nofIdentifiers) as ?maxNofIdentifers)
{
#
#  Use a subquery to prevent a timeout:
#
   {
      select distinct
         ?nofIdentifiers
      {
         [] wikibase:identifiers ?nofIdentifiers .
      }
   }
}

select
   ?x
{
   ?x wikibase:identifiers 833 .
}

wikibase:propertyType

select distinct
   ?propertyType
{
  [] wikibase:propertyType ?propertyType .
}
order by
  ?propertyType

select
   ?prop
   ?propLabel
{
   ?prop    wikibase:propertyType  <http://wikiba.se/ontology#GlobeCoordinate> .

    service wikibase:label { bd:serviceParam wikibase:language "en" . }
}

wikibase:lemma

select
   ?sub
   ?typ
   ?lem
   (datatype(?lem) as ?dtp)
{
   ?sub wikibase:lemma ?lem .
   ?sub rdf:type       ?typ .
}
limit 100

wikibase:lexicalCategory

select
   ?category
   ?categoryLabel
{
   hint:Query hint:optimizer "None".
   {
      select distinct
        ?category
     {
         [] wikibase:lexicalCategory ?category
     }
   }
   service wikibase:label { bd:serviceParam wikibase:language 'en,de,fr,de,ru,tg' . }
}
order by
   lcase(?categoryLabel)

wikibase:quantityAmount and wikibase:quantityUnit

select
   ?itemLabel
   ?elevation
   ?unitLabel
{

   values (?item)
   {
      ( wd:Q46588    )  # Cordillera Kimsa Cruz : a mountain range in Bolivia
      ( wd:Q499164   )  # Ascraeus Mons         : a martian shield volcano
      ( wd:Q55615607 )  # Kalindi Pass          : highest and most adventurous trekking trail in India (almost 6000 M)
   }

   ?item        p:P2044                 ?eleStmts    .
   ?eleStmts    psv:P2044               ?eleValues   .

   ?eleValues   wikibase:quantityAmount ?elevation   .
   ?eleValues   wikibase:quantityUnit   ?unit        .

   ?item        rdfs:label              ?itemLabel   .
   ?unit        rdfs:label              ?unitLabel   .

   filter(lang(?itemLabel) = 'en')
   filter(lang(?unitLabel) = 'en')
}

wikibase:rank

wikibase:sitelinks

select
   (max(?nofSitelinks) as ?maxNofSitelinks)
{
#
#  Use a subquery to prevent a timeout:
#
   {
      select distinct
         ?nofSitelinks
      {
         [] wikibase:sitelinks ?nofSitelinks .
      }
   }
}

select
   ?x
{
   ?x wikibase:sitelinks 873 .
}

wikibase:* TODO

schema:about

select
   ?wdNr
{
   <https://he.wikipedia.org/wiki/%D7%A6%D7%99%D7%A8%D7%99%D7%9A> schema:about ?wdNr .
}

select
   ?wikipediaURL
{
   ?wikipediaURL schema:about     wd:Q72                        .
   ?wikipediaURL schema:isPartOf <https://he.wikipedia.org/>    .
}

schema:Article

ask {
  <https://en.wikipedia.org/wiki/Wikidata>  rdf:type  schema:Article .
}

schema:dataset

select *
{
  ?subj rdf:type schema:Dataset .
}

schema:inLanguage

schema:name

select
   ?name
   ?wikimediaURL
{

   values (?name) {
     ("Auguste Piccard"     @fr)
     ("Oracle Database"     @en)
   }

   ?wikimediaURL schema:name ?name
}

select
  ?label
 (lang(?label) as ?lang)
{
   <https://de.wikipedia.org/wiki/London>  schema:name ?label .
}

schema:isPartOf

select ?partOf
{
   <https://de.wikisource.org/wiki/Das_Newe_Testament_Deutzsch> schema:isPartOf ?partOf
}

select distinct ?partOf
{
   $item schema:isPartOf ?partOf
}
order by
   ?partOf

schema:description

select
   ?descr
  (lang(?descr) as ?lang)
{
   wd:Q39 schema:description ?descr .
}

schema:* TODO:

Combining some schema:* relations

select
   ?term
  (lang(?term) as ?termLang)
   ?lang
   ?wikimediaURL
   ?wikidataID
   ?project
{

   values (?term) {
     ("Gift"@en)
     ("Gift"@de)
   }

   ?wikimediaURL schema:name       ?term       .
   ?wikimediaURL schema:about      ?wikidataID .
   ?wikimediaURL schema:isPartOf   ?project    .
   ?wikimediaURL schema:inLanguage ?lang       .
  
}

rdfs:label

select
  (lang(?label) as ?langId)
   ?label
{
   wd:Q39   rdfs:label  ?label .
}
order by
   ?langId

select
   ?label
{
   wd:Q39   rdfs:label  ?label .
   filter( lang(?label) = 'bn' )
}

rdf:type

owl:Ontology

select *
{
  ?subj rdf:type owl:Ontology .
}

prov:* TODO

skos:altLabel

select
   ?alias
{
   wd:Q39   skos:altLabel  ?alias .
   filter( lang(?alias) = 'en' )
}

ontolex:* TODO

dct:* TODO

Lexemes

select
   ?lexem
   ?gender
{
   ?lexem      rdf:type       ontolex:LexicalEntry .
   ?lexem      dct:language   wd:Q188              . # Q188:  German
   ?lexem      wikibase:lemma ?text                . filter(str(?text) = "Aprikose")
   ?lexem      wdt:P5185      ?gender_             . # P5185: grammatical gender
   ?gender_    rdfs:label     ?gender              . filter(lang(?gender) = 'de')
}

wdt:P…

p: connect wd:Q… to wds:…

select
   ?wds
   ?rel
   ?obj
{
   wd:Q544  p:P2670  ?wds .  # Q544 = Solar System
   ?wds     ?rel     ?obj .
}

ps: connect wds: to simple value

select
   ?wd
{
   wds:Q544-1edcc7b8-4eb3-28d9-35b5-b6ff5bbc8e38 ps:P2670 ?wd .
}

p: , ps: and pq:

#defaultView:LineChart
select
   ?year
   ?population
{
  wd:Q39          p:P1082  ?populationStmt .
  ?populationStmt pq:P585  ?year           ;
                  ps:P1082 ?population     .
  filter(year(?year) >= 1970)
}
order by
   ?year

psn:

pqv:

P31 / instanceOf

select
   ?cnt
   ?xLabel
   ?x
with {
   select
  (count(*) as ?cnt)
   ?x 
  {
     [] wdt:P31 ?x .
  }
  group by ?x
  order by desc(?cnt)
  limit 100
}
   as %I
{
   include %I 
   service wikibase:label { bd:serviceParam wikibase:language "en" . }
}
order by
   desc(?cnt)

DESCRIBE

describe <http://www.wikidata.org/entity/Q72>

Wikidata categories

select
   (count(*) as ?cntWikidataCategories)
{
   ?category  wdt:P31  wd:Q4167836 .
}

Disambiguation pages

ask {
   wd:Q399841  wdt:P31  wd:Q4167410 .
}

RDFS and OWL terms

The Wikidata schema avoids direct use of RDFS or OWL terms and redefines many of them, e.g. wkd:P31 defines a local property similar to rdf:type. There are attempts to connect Wikidata properties to RDFS/OWL and provide alternative exports of Wikidata data.

Finding an Wikidata item's corresponding DBpedia resource

select
   ?sub
{
   ?sub  owl:sameAs  <http://www.wikidata.org/entity/Q507459> .
}

Default View

#defaultView:LineChart
select ?x ?y {
   values (?x ?y) {
      ( 1  20)
      ( 6  23)
      ( 9  21)
      (11  19)
      (14  20)
      (15  22)
      (17  24)
   }
}

#defaultView:Map
select
 #
 # Use distinct to make all points on the map equally sized.
 # Some nodes are linked with both, Q23413 and Q17715832, and thus
 # would be drawn with a bigger point.
 #
   distinct
  ?name
  ?coord
{
   values (?castleType) {
      ( wd:Q23413    )
      ( wd:Q17715832 )
   }

   ?castle  wdt:P31    ?castleType ;
            p:P131     ?locStmt    ;
            wdt:P625   ?coord      ;
           rdfs:label  ?name       .

   ?locStmt ps:P131     wd:Q11943  .

   filter(lang(?name) = 'de')
}

#defaultView:Map
select
  *
{
   values (?coord ?text) {
       ( "Point(-6.4456011 49.872861 )"^^geo:wktLiteral  "Bishop Rock"   @en )
       ( "Point(-6.4172637 49.878124 )"^^geo:wktLiteral  "Isles of Scily"@en )
   }
}

#defaultView:Map{"layer": "?suffix"}
select
   ?munic
   ?name
   ?coord
  (if(regex(?name, 'wil$'  ), '-wil',
   if(regex(?name, 'wilen$'), '-wilen',
   if(regex(?name, 'ikon$' ), '-ikon',
   if(regex(?name, 'iken$' ), '-iken',
   if(regex(?name, 'rach$' ), '-rach',
   if(regex(?name, 'ingen$'), '-ingen',
   if(regex(?name, 'au$'   ), '-au',
   if(regex(?name, 'bach$' ), '-bach',
   if(regex(?name, 'berg$' ), '-berg',
    "*")))))))))  as ?suffix)
with { # Use named subquery (which is guaranteed to be run only once) to improve performance
      select
         ?munic
        (replace(?name, '(.*) \\w\\w$', '$1') as ?name)  # Remove occasional Canton abbreviation (for example 'Oberdorf BL')
      {
         ?munic  wdt:P31     wd:Q70208 ;
                 wdt:P625   ?coord     ;
                 rdfs:label ?name .
        filter(lang(?name) = 'de')
      }
} as %municipalities
where {
   include %municipalities
   ?munic       wdt:P625   ?coord     .
}

Mountains higher than 4000 meters in Switzerland

select
   ?elevation
   ?name
   ?mountain
{

  ?mountain wdt:P31      wd:Q8502   ; # ?mountain is an "instance of" (P31) a "mountain" (Q8502)
            wdt:P17      wd:Q39     ; # ?mountain has "country" (P17) "Switzerland" (Q39)
            wdt:P2044    ?elevation ; # P2044: "elevation above sea level"
            rdfs:label   ?name      . # Use rdfs:label to find the mountain's name

            filter(?elevation >= 4000)
            filter(lang(?name) = 'de')
}
order by
  ?elevation

Most common relations

select
   ?rel
   (count(?rel) as ?cnt)
{
   select ?rel
   {
      ?x  ?rel ?y .
   }
   limit 10000000
}
group by
   ?rel
order by
   desc(count(?rel))
limit
   100

select
   ?cnt
   ?rel_
   ?relLabel
with {
#
#  Use named subquery (which is guaranteed to be run only once) to improve performance
#
   select
       ?rel_
      (count(*) as ?cnt)
   {
      [] ?rel_ [] 
   }
   group by ?rel_
   order by desc(?cnt)
   limit 400             # not every relation will be matched below...
} as %rels
where {
   include %rels .
   optional { ?rel wikibase:directClaim ?rel_ . 
              ?rel rdfs:label ?relLabel . filter(lang(?relLabel) = 'en') . }
}
order by desc(?cnt)

select
   ?cnt
   ?rel_
   ?relLabel
with { # Use named subquery (which is guaranteed to be run only once) to improve performance
   select
       ?rel_
      (count(*) as ?cnt)
   {
      [] ?rel_ [] 
   }
   group by ?rel_
   order by desc(?cnt)
   limit 400             # not every relation will be matched below...
} as %rels
where {
   include %rels .
   ?rel wikibase:directClaim ?rel_ . 
   ?rel rdfs:label ?relLabel . filter(lang(?relLabel) = 'en') .
}
order by desc(?cnt)

All objects of a given node

select
   ?relText
   (coalesce(?xText, ?x) as ?obj)
   ?rel_
   ?relType
#  ?x
#  ?xText
{

#  wd:Q35120  ?rel                   ?x       .
   wd:Q39     ?rel                   ?x       .

   ?rel_      wikibase:directClaim   ?rel     .
   ?rel_      rdfs:label             ?relText . filter(lang(?relText) = 'en')
   ?rel_      wikibase:propertyType  ?relType .
  
  
   optional {
   ?x         rdfs:label             ?xText   . filter(lang(?xText  ) = 'en')
   }
}
order by
   lcase(?relText)

wd:Q23958852

ask {
   wd:Q23958852  wdt:P31  wd:Q23958852 .
}

Queries on the Wikimedia Commons endpoint

select *
{
   ?x ?y ?z 
   filter (?y != schema:dateModified)
}
limit 100

select *
{
   ?x
   ps:P921        # Main subject
   wd:Q28048087 . # Benjamin Franklin
}

select * {
  ?x schema:contentUrl <https://upload.wikimedia.org/wikipedia/commons/f/fd/Matterhorn_from_Switzerland.jpg> ;
     ?rel               ?obj
}