SAS: proc export

Export data set to a .txt file

data tq84_data;

  infile datalines;

  length col_1 $10
         col_2 $10
         col_3 $10;

  input col_1 col_2 col_3;

datalines;
x y z
one two three
foo bar baz
strawberry blackberry blueberry
;

proc export
     data=tq84_data
     outfile='p:\ath\to\exported.txt';
     putnames=no;
run;

Using the keep option

data tq84_data;

  infile datalines;

  length col_1 $10
         col_2 $10
         col_3 $10;

  input col_1 col_2 col_3;

datalines;
x y z
one two three
foo bar baz
strawberry blackberry blueberry
;

proc export
     data=tq84_data(keep=col_1 col_3)
     outfile='p:\ath\to\exported.txt';
     putnames=no;
run;

Using the replace option

data tq84_data;

  infile datalines;

  length num   8
         txt  $20
  ;

  input num txt;

datalines;
1 one
2 two
3 three
4 four
5 five
6 six
7 seven
8 eight
9 nine
10 ten
;
run;

proc export

     data=tq84_data (where=(txt gt 'm'))
     outfile='p:\ath\to\exported.txt'
     
     replace;
     putnames=no;
     
run;

Create an Excel file

data tq84_xls;
     do num = 1 to 100;
        txt = put(num, words30.);
        output;
     end;
run;

%let xls_file_name=p:\ath\to\excel\file.xls;

proc export
     data    = tq84_xls
     dbms    = xls
     outfile ="&xls_file_name";

     sheet="all";
run;


proc export
/*   Sine &xls_file_name already exists, a *.bak file
     will additionally be created. */ 

     data    = tq84_xls(where=(num <= 10))
     dbms    = xls
     outfile ="&xls_file_name";

     sheet="first ten";
run;

See also